小技集

野外イベントなどで販売数を管理しながら受付業務を行う際、商品が購入される度、販売数の数値を直接入力するのは大変です。
そのため、こちらでは、特定の商品の販売数のセルをダブルクリックするだけで、その販売数に１を加えることができる機能を開発していきます。
また、何かしらの原因でデータが紛失しないように、販売数を加算する度、自動で保存される機能も加えていきます。

こちらでは、以下の商品ごとの販売数を管理した表を活用して開発していきます。

※こちらで開発したファイルは記事の最後にて配布しています。

開発準備

「特定のセルをダブルクリックすると同時に、何かしら処理を実行する」という仕組みは、該当するシートモジュールのイベントプロシージャを活用することで実現できます。

シートモジュールは、該当するシートのタブ上で右クリックし、[コードの表示]を選択することで表示することができます。

選択すると、以下のエディタ画面（VBE）が表示されます。
また、該当するシートのシートモジュールが表示された状態になります。
「Option Explicit」は、VBEの設定内容次第では表示されません。「Option Explicit」についての解説はこちらでは省略します。

次に、該当するシートのセルをダブルクリックすると同時に処理が実行される特殊なプロシージャ（イベントプロシージャ）を用意する必要があります。
そのためには、シートモジュールの左上のリストから「Worksheet」を選択します。

「Worksheet」を選択すると、自動で「Worksheet_SelectionChange」というプロシージャが表示されます。
このプロシージャは、該当するシート上のいずれかのセルが選択されると同時に処理が実行されるイベントプロシージャと呼ばれるものになります。

ただ、今回使用するイベントプロシージャは、セルがダブルクリックされると同時に処理が実行されるものになります。
そのため、右上のリストから「BeforeDoubleClick」を選択します。

表示された「Worksheet_BeforeDoubleClick」というプロシージャを活用します。
「Worksheet_SelectionChange」というプロシージャに関しては削除して問題ないです。

コードの記述

以下のコードを記述します。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    
    If Target.Column = 3 And _
        Target.Row >= 3 And _
        Target.Row <= 20 Then
        
        Cancel = True
        Target.Value = Target.Value + 1
        ThisWorkbook.Save
        
    End If
    
End Sub

では、コードについて解説していきます。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    
    If Target.Column = 3 And _
        Target.Row >= 3 And _
        Target.Row <= 20 Then

        '省略

    End If
    
End Sub

「Worksheet_BeforeDoubleClick」というプロシージャの引数の「Target」に、ダブルクリックされたセルの情報が渡されるため、そのセルの情報から、表の対象の範囲内がダブルクリックされたのかどうかを確認しています。
こちらでは、「３列目、尚且つ、３～２０行目の間のセル」と販売数のセルの範囲内がダブルクリックされたかどうかを確認しています。

この条件を満たした場合に関してのみ、Ifの中の処理を実行します。

        Cancel = True
        Target.Value = Target.Value + 1
        ThisWorkbook.Save

セルをダブルクリックすると、通常、セルが編集モードになるのですが、引数の「Cancel」をTrueにすることで、編集モードにならなくなります。
その後、ダブルクリックされたセルの値に１を加えて、ブックを保存しています。

以上の内容で実現できます。
販売数のセルをダブルクリックすることで、ダブルクリックされたセルの値に１を加えて、ブックが保存されます。

▼サンプルファイル▼

以下の表では、氏名を入力した後にクラスを入力するだけで、自動で該当するクラスの位置に移動するようになっています。

このような、特定の項目に値を入力すると同時に、その項目を基準に自動で並べ替えするという機能の開発方法について解説していきます。
※こちらで開発したファイルは記事の最後にて配布しています。

開発準備

「特定のセルに値を入力すると同時に、何かしら処理を実行する」という仕組みは、該当するシートモジュールのイベントプロシージャを活用することで実現できます。

シートモジュールは、該当するシートのタブ上で右クリックし、[コードの表示]を選択することで表示することができます。

選択すると、以下のエディタ画面（VBE）が表示されます。
また、該当するシートのシートモジュールが表示された状態になります。
「Option Explicit」は、VBEの設定内容次第では表示されません。「Option Explicit」についての解説はこちらでは省略します。

次に、セルに値を入力すると同時に処理が実行される特殊なプロシージャ（イベントプロシージャ）を用意する必要があります。
そのためには、シートモジュールの左上のリストから「Worksheet」を選択する必要があります。

次に、隣のリストから「Change」を選択します。

「Change」を選択すると表示される「Worksheet_Change」というプロシージャ内にコードを記述します。
他のプロシージャに関して、使用していない場合は削除して問題ないです。

コードの記述

以下のコードを記述します。

Private Sub Worksheet_Change(ByVal Target As Range)
    
    Dim rng As Range
    For Each rng In Target
        If rng.Column = 2 Then
            Range("B2").Sort _
                Key1:=Range("B2"), _
                Order1:=xlAscending, _
                Header:=xlYes
        End If
    Next rng
    
End Sub

では、コードについて解説していきます。

Private Sub Worksheet_Change(ByVal Target As Range)

「Worksheet_Change」というプロシージャは、該当するシートのセルが編集されると同時に実行されます。
その際、編集されたセルの情報が引数の「Target」に渡されます。
引数の「Target」を活用して、今回の場合は、クラスの項目（列）が編集されたかどうかを判断し、編集された場合に、その項目（列）を基準に昇順に並べ替えを行います。

    Dim rng As Range
    For Each rng In Target
        If rng.Column = 2 Then
            '省略
        End If
    Next rng

今回の場合、同時に編集されたセルは１つであることが多いかと思いますが、複数セルが同時に編集することもあります。（コピー＆ペーストやCtrlキーを押しながらの同時入力など）
複数セルを同時に編集した場合は、引数の「Target」に複数セルの情報が渡されます。
そのため、複数セルの同時入力を考慮し、「Target」のセルの情報をFor Eachで１つずつを変数「rng」に渡して確認しています。

次に、変数「rng」の列番号が２、即ち、B列のクラスの項目の位置であることを確認しています。B列の場合のみに次の処理を実行します。
※必要に応じて「行番号が３以上の場合」などといった条件を加えても良いです。

            Range("B2").Sort _
                Key1:=Range("B2"), _
                Order1:=xlAscending, _
                Header:=xlYes

こちらで、セルB2が含まれる表に対し、「Sort」で並べ替えを行っています。
「Key1:= Range(“B2”)」でセルB2の属する列を並べ替えの基準の列として指定し、「Order1:=xlAscending」で昇順を指定、「Header:=xlYes」で項目名を含む範囲ということを指定しています。

以上の内容で実現できます。
クラスの項目に値を入力すると同時に、自動で並べ替えられます。

▼サンプルファイル▼

以下のように、同じ形式の予定表が複数シートに用意されている場合で、それぞれの予定表の特定の時間に同じ予定を一括で登録する機能の開発方法について解説していきます。

※こちらで開発したファイルは、記事の最後にて配布しています。

開発準備

まず初めに、[開発]タブを選択し、[マクロ]を選択します。

表示された以下の画面にて、開発する機能の名前を入力し、[作成]を選択します。
こちらでは、「setSchedule」と入力しています。

次に表示される以下の画面の「Sub ○○」から「End Sub」の間にコードを記述します。

コードの記述

以下のコードを記述します。

Sub setSchedule()
    
    Dim mWs As Worksheet
    Set mWs = Worksheets("反映")
    
    Dim ws As Worksheet
    Dim i As Long
    
    For i = 4 To 33
        If mWs.Cells(i, "B").Value <> "" Then
            For Each ws In Worksheets
                If ws.Name <> mWs.Name Then
                    If InStr(ws.Cells(i, "B").Value, _
                        mWs.Cells(i, "B").Value) = 0 Then
                        
                        ws.Cells(i, "B").Value = _
                            mWs.Cells(i, "B").Value & vbLf & _
                            ws.Cells(i, "B").Value
                        
                    End If
                End If
            Next ws
        End If
    Next i
    
End Sub

では、コードについて解説していきます。

    Dim mWs As Worksheet
    Set mWs = Worksheets("反映")

反映元となるシート情報を変数「mWs」に割り当てています。

    Dim ws As Worksheet
    Dim i As Long

繰り返し処理で扱う変数を定義しています。
変数「ws」は各シートを繰り返す際に活用し、変数「i」は各行を繰り返す際に活用します。

    For i = 4 To 33
        If mWs.Cells(i, "B").Value <> "" Then
            For Each ws In Worksheets
                If ws.Name <> mWs.Name Then
                    '処理
                End If
            Next ws
        End If
    Next i

Forで反映シートの予定表の先頭行から最終行までを繰り返し、内側のIfで予定が空でない場合に関してのみ、更に内側のFor Eachを実行するように記述しています。

For Eachでは、存在するシート１つ１つのシート情報を順番に変数「ws」に割り当て、更に内側のIfでシート名が「反映」でない場合に関してのみ、最深部の処理を実行するように記述しています。

                    If InStr(ws.Cells(i, "B").Value, _
                        mWs.Cells(i, "B").Value) = 0 Then
                        
                        ws.Cells(i, "B").Value = _
                            mWs.Cells(i, "B").Value & vbLf & _
                            ws.Cells(i, "B").Value
                        
                    End If

最深部では、Ifで反映元のシートの対象行「i」の予定と同じ予定が登録されていないことを確認しています。
InStrを活用して、反映先のシート「ws」の対象行「i」のセルに、反映元のシート「mWs」の対象行「i」のセルの値が含まれているかどうかを判定しています。
InStrで含まれていないと判断された場合は、「0」を返します。
そのため、その結果が「0」の場合という条件式になっています。

この条件を満たしたときに、反映先のシート「ws」の対象行「i」のセルに元々入力されている値に対し、改行「vbLf」と反映元のシートの対象行「i」のセルの値を加えています。

ボタンの作成

コードが完成しましたら、反映シートに実行ボタンを用意します。
実行ボタンは、[開発]タブの中の[挿入]から作成することができます。

完成

以上の手順で、機能が完成します。
反映シートの10:00の予定（セルB8）に「共通の予定」と入力して、「一括反映」ボタンを押した実行結果は、以下になります。

既存の予定が存在する場合は、その予定を残したまま、先頭に「共通の予定」が追加されます。

▼サンプルファイル▼

以下の表のように、特定の項目（カテゴリー）の値単位で交互に自動で色付けする方法について解説していきます。

※こちらで使用したファイルは記事の最後にて配布しています。

条件式の作成

まずは、色付けする行の条件式を作成していきます。
色付けする行の条件式は、以下の手順で作成していきます。

1.カテゴリーの重複を除いた表を用意
2.対象行のカテゴリーが重複を除いた表の上から何番目なのかを求める
3.（2）で求めた数値が偶数の場合にTRUEと表示する

では順番に作成していきます。

1.カテゴリーの重複を除いた表を用意

まずは、カテゴリーの重複を除いた表の用意です。
重複を除いた表を用意する際は、UNIQUE関数を活用します。
この関数の使い方は、以下になります。

=UNIQUE(配列, [列の比較], [回数指定])
// 配列：対象のデータの範囲
// [列の比較]：データが列方向の場合(TRUE)、行方向の場合(FALSE[省略時])
// [回数指定]：重複していないデータのみを抽出する場合(TRUE)、重複を除いた全件を抽出する場合(FALSE[省略時])

実際にUNIQUE関数を活用して数式を作成すると、以下のようになります。

=UNIQUE(C3:C100)
// 表の範囲は100行目までとする

※空白のセルは「0」として抽出されます。

2.対象行のカテゴリーが重複を除いた表の上から何番目なのかを求める

次に、それぞれの行のカテゴリーが先ほど抽出した表の何番目になるのかをMATCH関数を活用して求めます。
この関数の使い方は、以下になります。

=MATCH(検査値, 検査範囲, [照合の種類])
// 検査値：検索する値
// 検査範囲：検索する範囲
// [照合の種類]：(1)以下、(0)完全一致、(-1)以上（省略時は(1)が指定される）

実際にMATCH関数を活用して数式を作成すると、以下のようになります。

=MATCH(C3,UNIQUE(C3:C100),0)
// C3：検索する値
// UNIQUE(C3:C100)：検索する範囲（直接UNIQUE関数を指定）
// 0：完全一致で検索

他の行でも、正しく求めることができることを確認します。
そのため、数式の中のカテゴリーの項目の範囲を絶対参照にします。
検査値に関しては、列方向に反映した際に、参照列が移動しないように列のみを絶対参照にします。

=MATCH($C3,UNIQUE($C$3:$C$100),0)

この数式を下へコピーすることで、カテゴリーが切り替わる位置で数値をカウントアップすることができます。

カテゴリーが入力されていない行に関しては、エラーが表示されます。
理由は、UNIQUE関数で抽出した値に空が存在しないためです。
（UNIQUE関数で抽出した値では、空が「0」になってしまっているため、空ではヒットしません。）

一度、エラーはこのままにしておきます。

3.（2）で求めた数値が偶数の場合にTRUEと表示する

次は、先ほどMATCH関数で抽出した、それぞれの値が偶数の場合にTRUEと表示する数式を作成していきます。

偶数かどうかを判定する場合は、ISEVEN関数を活用します。
この関数の使い方は、以下になります。

=ISEVEN(数値)
// 数値：対象の数値

実際にISEVEN関数を活用して数式を作成すると、以下のようになります。

=ISEVEN(MATCH($C3,UNIQUE($C$3:$C$100),0))

この数式を下へコピーすることで、偶数番目のカテゴリーのみにTRUEと表示することができます。

ただ、空白の場合にエラーになってしまうので、エラーに関しては、IFERROR関数を活用してFALSEと表示するようにしていきます。
この関数の使い方は、以下になります。

=IFERROR(値, エラーの場合の値)
// 値：エラーを検証する値
// エラーの場合の値：値がエラーの時に表示する値

実際にIFERROR関数を活用して数式を作成すると、以下のようになります。

=IFERROR(ISEVEN(MATCH($C3,UNIQUE($C$3:$C$100),0)),FALSE)

この数式を下へコピーすることで、偶数番目のカテゴリーのみにTRUEと表示することができます。

このように条件式を作成することができましたら、後は条件付き書式で設定してきます。

条件付き書式の設定

まずは、色付けする可能性のある対象の範囲を全選択します。

先ほど作成した条件式は３行目を基準とした１００行目までに対応させた数式になります。
そのため、セルB3を基準にD100までを選択します。

名前ボックスを活用することで、簡単に選択することができます。

選択できましたら、[ホーム]タブの中の[条件付き書式]から[新しいルール]を選択します。

条件付き書式の設定画面にて、[ルールの種類]を[数式を使用して、書式設定するセルを決定]にし、表示されたテキストボックス内に、先ほどの条件式を入力します。
※アクティブセルに対する条件式を入力します。

条件式の入力ができましたら、[書式]を選択し、好みの書式を設定します。
こちらでは、書式設定の画面にて、[塗りつぶし]から灰色を設定します。

上記のように設定して確定することで、以下のように、カテゴリー単位で交互に自動で色付けすることができます。

※広範囲に設定すると、Excelファイルが重たくなります。そのため、今回のように１００行目までなどと必要最低限の範囲にしておくとよいです。

▼サンプルファイル▼