小技集

外部から出力したファイルなどで、以下のように日付が８桁の数値で出力されている場合があります。

ただ、このままですと、日付として扱うことができません。
そのため、集計には不向きになります。

今回は、上記のような８桁の数値の日付を日付形式に変換する方法について解説していきます。

見た目のみを日付形式にする

まずは、表示形式を用いて、見た目のみを日付形式にしてみます。

８桁の数値が入力されている範囲を選択し、表示形式の設定から[その他の表示形式]を選択します。

以下の画面にて、[ユーザー定義]を選択し、「#-00-00」と入力します。

「#」は数値を表し、「0」は０埋めの数値を表します。
そのため、元の８桁の数値の先頭から２つは０埋めで表示し、次に「-」、そして、次の２つを０埋めで表示し、また「-」、後は残りの数値を「#」で表示しています。
この設定内容で確定することで、以下のように「-」区切りに日付形式の見た目にすることができます。

※「-」ではなく「/」にする場合は、「#”/”00″/”00」と「/」を「”」で囲む必要があります。

値を日付形式に変換する

前半の手順ですと、あくまで見た目のみの対応になります。
そのため、集計には向いていません。

集計がしやすいようにするため、次は、見た目ではなく実際の値を日付形式にしていきます。

まずは、先ほど設定した表示形式を「標準」に戻します。

※実際の値が分かりづらいため、元の８桁の数値に戻しています。

では、隣のセル（C列）に日付形式にした値を表示していきます。

初めに、TEXT関数を用いて、日付形式にする表示形式（前半に設定した内容）を適用した文字列を取得します。
TEXT関数の使い方は、以下になります。

=TEXT(値, 表示形式)
// 値：対象の値
// 表示形式：対象の値に対し、適用したい表示形式

実際に以下のように入力して、表示形式を適用した文字列を取得します。

=TEXT(B2,"#-00-00")

文字列として取得できましたら、次は、この文字列を日付に変換する必要があります。
日付を表す文字列から日付に変換する場合は、DATEVALUE関数、もしくはVALUE関数を活用します。
これらの使い方は、以下になります。

=DATEVALUE(日付文字列)
// 日付文字列：日付を表す文字列

=VALUE(文字列)
// 文字列：数値や日付などを表す文字列

こちらでは、VALUE関数を用いて、以下のように入力します。

=VALUE(TEXT(B2,"#-00-00"))

上記のように、日付を表す数値（シリアル値）を取得できましたら、表示形式を日付形式にすることで完成です。

他の行のセルには、先頭の数式をコピーするだけで変換できます。

補足

日付の文字列を数値に変換する際に、先ほどはVALUE関数を活用しましたが、数値による計算を行うことでも変換することができます。
例えば、以下のような方法があります。

=0+TEXT(B2,"#-00-00")
=1*TEXT(B2,"#-00-00")
=--TEXT(B2,"#-00-00") 
// 「--」は-1×-1×[値]という意味になる
// ※「++」では変換できないので注意

以下の表で、氏名が入力されている行に対し、未割当（役割A～Eのいずれも値が入力されていない）の行の全体を自動で色付けする方法について解説していきます。

条件式の作成

まずは、色付けする条件式を作成していきます。
例えば、以下のセルB3を色付けする場合の条件について考えていきます。

セルB3を色付けする時の条件は、以下になります。

・B列（氏名）に値が入力されていて、同じ行のC～G列（役割A～E）が全て空の場合

これを数式で求めていきます。

①B列に値が入力されているかどうかの条件式は、以下になります。

=B3<>""
// セルB3が空でない場合

②特定のセルに値が入力されているかどうかは、『COUNTA関数』で求めることができます。
COUNTA関数の使い方は、以下になります。

=COUNTA(値1, [値2], [値3], …)
// 指定したセルの中で、空でないセルの数を返す
// 値：対象のセルの範囲（[値2]以降は省略可能）

COUNTA関数の引数に設定するセルは、該当する行のC～G列（役割A～E）になります。
そして、その範囲が空の場合という条件になるため、COUNTA関数の結果が「0」であることを確認します。
実際に数式で表現すると、以下になります。

=COUNTA(C3:G3)=0

①と②の式を組み合わせると、以下になります。

=AND(B3<>"", COUNTA(C3:G3)=0)
// AND関数を用いて「尚且つ」という条件式にする

この数式を他のセルにコピーしても反映できるように、「$」を加えて一部の参照を固定します。
今回の表の場合、どのセルに関しても、氏名はA列、役割はC～G列を参照する必要があります。
そのため、以下のように列を固定します。

=AND($B3<>"", COUNTA($C3:$G3)=0)

このように条件式を作成することができましたら、後は条件付き書式で設定してきます。

条件付き書式の設定

まずは、色付けする可能性のある対象の範囲を全選択します。

先ほど作成した条件式はセルB3に対する条件式であったため、選択基準のセル（アクティブセル）をセルB3にしています。

選択できましたら、[ホーム]タブの中の[条件付き書式]から[新しいルール]を選択します。

条件付き書式の設定画面にて、[ルールの種類]を[数式を使用して、書式設定するセルを決定]にし、表示されたテキストボックス内に、先ほどの条件式を入力します。
※アクティブセルに対する条件式を入力します。

条件式の入力ができましたら、[書式]を選択し、好みの書式を設定します。
こちらでは、書式設定の画面にて、[塗りつぶし]から黄色を設定します。

上記のように設定して確定することで、以下のように、氏名が入力されていて、尚且つ、未割当（役割A～Eのいずれも値が入力されていない）の行全体の色を変更することができます。

以下のような、横向きの年月日が別々のセルに入力されているスケジュール表で、ファイルを開く度に、今日の日付の列を自動で色付けする方法について解説していきます。

条件式の作成

まずは、色付けする条件式を作成していきます。
例えば、以下のセルD5を色付けする場合の条件について考えます。

セルD5を色付けする時の条件は、以下になります。

・今日の日付が2024/10/1の場合

これを数式で求めていきます。

今日の日付は『TODAY関数』で求めることができ、2024/10/1という日付は『DATE関数』で求めることができます。
それぞれの関数の使い方は、以下になります。

=TODAY()
// 今日の日付を返す

=DATE(年, 月, 日)
// 指定した年月日から該当する日付を返す

DATE関数の引数に設定する年月日に関しては、それぞれ以下のセルになります。

年：B2
月：D2
日：D3

実際に条件を数式で表現すると、以下になります。

=TODAY()=DATE(B2,D2,D3)

この数式を他のセルにコピーしても反映できるように、「$」を加えて一部の参照を固定します。
今回の表の場合、年のセルはB2、月のセルは2行目、日のセルは3行目で固定になります。
それを数式で表現すると、以下になります。

=TODAY()=DATE($B$2,D$2,D$3)

このように条件式を作成することができましたら、後は『条件付き書式』で設定してきます。

条件付き書式の設定

まずは、色付けする可能性のある対象の範囲を全選択します。

先ほど作成した条件式は、セルD5に対する条件式であったため、選択した後に、セルD5をアクティブセルにします。
アクティブセルを移動する場合は、EnterキーとTabキーを活用します。

・下へ移動：Enter
・上へ移動：Shift + Enter
・右へ移動：Tab
・左へ移動：Shift + Tab

以下のように、セルD5をアクティブセルにしてから、条件付き書式を設定していきます。

アクティブセルの変更ができましたら、[ホーム]タブの中の[条件付き書式]から[新しいルール]を選択します。

条件付き書式の設定画面にて、[ルールの種類]を[数式を使用して、書式設定するセルを決定]にし、表示されたテキストボックス内に、先ほどの条件式を入力します。
※アクティブセルに対する条件式を入力します。

条件式の入力ができましたら、[書式]を選択し、好みの書式を設定します。
こちらでは、書式設定の画面にて、[塗りつぶし]から薄い青色を設定します。

以上のように設定して確定することで、以下のように、今日の日付（2024/10/16）の列の色を変更することができます。

以下の表のように、それぞれの商品の在庫数が、それぞれに設定した安全在庫数未満になった場合に、その在庫数の文字の色を自動で赤色にする方法について解説していきます。

特定の条件を満たしたセルに対して、特定の書式を設定する場合は、『条件付き書式』を活用します。

条件付き書式の条件設定

まず初めに、文字の色を赤色にする可能性のある範囲（在庫数の範囲）を全選択します。

選択後、[ホーム]タブの中の[条件付き書式]から[新しいルール]を選択します。

表示された以下の画面にて、[ルールの種類]を[指定の値を含むセルだけを書式設定]にし、[ルールの内容]を「[セルの値]→[次の値より小さい]→”=$D3″」と指定します。
“=$D3″に関しては、テキストボックス内を選択した後に、セルD3を選択し、F4キーを２回押すことで簡単に入力することができます。
※こちらでは、アクティブセルがC3だったため、同じ行の安全在庫数のセルD3を指定しています。アクティブセルが異なる場合は、アクティブセルに対する安全在庫数のセルを指定する必要があります。

テキストボックス内に指定した”=$D3″に関しては、他の選択範囲にも行番号が相対参照で反映されます。
F4キーを押さないと”=$D$3″と行番号が絶対参照のままになってしまうため、今回はF4キーを２回押して”=$D3″にすることで、安全在庫数を参照する位置が行ごとに相対的に変わるようにしています。

条件付き書式の書式設定

最後に、条件を満たした時に反映させる書式を設定します。
こちらでは、[書式]を選択し、表示された[セルの書式設定]の[フォント]タブから色を赤色にしています。

以上の設定で[OK]を選択し、設定画面を閉じることで設定完了です。
各商品に対し、在庫数が安全在庫数を満たしていない場合に、文字の色が自動で赤色になります。

以下のグラフは、以下の表のAグループの値（担当A、B）を参照したものになります。

このグラフにBグループの値（担当C、D、E）を追加する場合、グラフを選択してから参照範囲をドラッグして拡張すると、以下のように、余分なデータ（Bグループというタイトル行）が含まれてしまいます。

こちらでは、余分なデータを含まずに、必要なデータのみを瞬時に追加する方法について解説していきます。

データの追加

グラフにデータを追加する場合、ドラッグ操作以外にも[グラフのデザイン]タブの[データの選択]から追加する方法もありますが、若干手間になります。

実は、「コピー＆ペースト」を使うことで、効率的にデータを追加することができます。

まずは、追加したい範囲を以下のように選択し、Ctrlキーを押しながらCキーを押してコピーします。

次に、データを追加したい対象のグラフを選択し、Ctrlキーを押しながらVを押して貼り付けます。
これだけで、グラフにデータを追加することができます。

元々の参照範囲から離れているデータを追加する際に、より効率的に追加することができます。

データの削除

一部のデータを削除する場合は、対象の系列を選択してDeleteキーを押すだけで、簡単に削除することができます。

表の中を選択して、Ctrlキーを押しながらAキーを押すことで、表を全選択することができます。

上記の内容は、一般的な活用例になります。
こちらでは、「Ctrl+A」の別の活用例を紹介していきます。

検索画面での活用

別の活用例とは、『検索画面』での活用になります。
実は、検索画面に表示された検索結果を全て選択する際にも活用できます。

例えば、以下の表から「着手中」という文字を全て選択する場合、検索画面を開き（Ctrl+F）、「着手中」という文字を入力して、[すべて検索]のボタンを押します。

※予め指定した範囲の中から検索したい場合は、検索対象のセルを選択している状態で、検索画面を操作します。

以下のように、検索結果に複数件が表示されている場合は、Ctrlキーを押しながらAキーを押すことで、検索結果の全てのセルを選択することができます。

全てのセルを選択した後は、Enterキー、もしくはTabキーを押して、対象のデータを１件ずつ確認することが出来ますし、編集が必要な場合は、そのまま編集することができます。
選択しているセルの値を完全に書き換える場合は、直接、値を入力すればよいですし、値の一部を編集する場合は、F2キーを押すことで、セル内にカーソルを表示させ編集することができます。

指定した項目の要素別の表を瞬時に作成する方法について解説していきます。
こちらでは、以下の氏名と部署で構成された表から部署単位の表を作成する方法を例に解説します。

氏名と部署で構成された表から部署単位の表を作成する

表の中から特定の条件を満たした要素のみを抽出する場合は、FILTER関数が便利です。
FILTER関数は、Microsoft365もしくはExcel2021以降で対応している関数になります。

FILTER関数の使い方は、以下になります。

=FILTER(配列, 含む, [空の場合])
// 配列：抽出対象の表
// 含む：抽出条件
// [空の場合]：抽出対象が存在しない場合に表示する値（省略可能）

実際に、以下の表から部署が「営業部」の氏名のみを抽出してきます。

そのような場合は、以下のような数式になります。

=FILTER(B:B,C:C="営業部","")
// B:B：抽出対象の氏名の列全体を指定
// C:C="営業部"：部署の項目で「営業部」が入力されているデータのみが抽出対象
// ""：データが存在しない場合は何も表示しない

また、「営業部」に関しては、セルの値を参照して以下のように表現することもできます。

=FILTER(B:B,C:C=E2,"")

こちらの数式を隣のセルにコピーするだけで、他の部署に関しても抽出できるようにしてきます。
その際は、抽出対象の範囲（氏名の項目）と抽出条件の範囲（部署の項目）が相対的に移動しないように、以下のように「$」で固定します。

=FILTER($B:$B,$C:$C=E2,"")

後は、この数式を一番左の「総務部」までコピーします。

これだけで、２行目（セルE2~G2）の「営業部、人事部、総務部」を抽出条件とし、瞬時に、対象の氏名のみを抽出することができます。

コピーすることでセルG3までに入力された数式は、以下になります。

E3：=FILTER($B:$B,$C:$C=E2,"")
F3：=FILTER($B:$B,$C:$C=F2,"")
G3：=FILTER($B:$B,$C:$C=G2,"")

以下のような請求書のフォーマットに対し、セルF2の請求書Noを入力すると同時に、摘要欄の内容を別シート（請求管理）から抽出し表示する方法について解説していきます。

摘要欄の抽出

実現するためには、『FILTER関数』を活用します。
FILTER関数は、Excel2021以降で対応している関数になります。

FILTER関数は、指定した表から指定した条件を満たしたデータのみを抽出する関数になります。
この関数の使い方は以下の通りです。

=FILTER(配列, 含む, [空の場合])
// 配列：抽出対象の表
// 含む：抽出する条件
// [空の場合]：抽出対象が存在しない場合に表示する値（省略可能）

こちらの場合、「請求管理」シートから該当する「商品名、数量、単位、単価」を抽出します。

抽出条件は、「「No」が請求書Noと一致する場合」になります。

では、「FILTER関数」を活用して抽出していきます。

抽出する際は、抽出したい位置の先頭のセルに数式を入力します。
こちらでは、摘要欄の先頭のセルB15に数式を入力していきます。

入力する数式は、以下になります。

=FILTER(請求管理!D:G,請求管理!B:B=F2,"")
// 抽出対象の表：請求管理!D:G（今後データが追加されることを考慮し列全体を指定）
// 抽出する条件：請求管理!B:B=F2（請求管理シートのB列のNoが請求書Noと一致する場合）
// 見つからない場合：""（何も表示しない）

これだけで、今後は、セルF2の請求書Noを変更するだけで摘要欄を抽出することができます。
他の項目（請求日、宛名、件名、支払期日、振込先）に関しても別のシートで管理している場合は、請求書Noと紐づけて、今回のFILTER関数や他にもVLOOKUP関数、XLOOKUP関数などを用いて抽出することで、請求書の入力を効率化することができます。

他の書類に関しても、同様に活用できます。