KE2

以下の表のように、マークされた行を瞬時に削除するマクロの開発方法について解説していきます。
※完成ファイルは配布しています。

このような仕組みをVBAで開発するには、どのような処理で実現するのかを考える必要があります。
今回の場合は、以下のような処理で実現できるかと思います。
※このような処理の流れを表現した図をフローチャートと呼びます。

処理を上記のように分解することができましたら、１つ１つVBAで実現していきます。

まずは、[開発]タブより[マクロ]を選択し、好みの名前（こちらでは”対象行の削除”）を入力し、[作成]を選択します。

表示された「Sub 対象行の削除()」内に以下のようなコードを記述します。
※「’」から始まっている緑の文字はコメントアウトと呼び、処理には関係のないメモ書きになります。

Sub 対象行の削除()
    
    Dim lastRow As Long
    
    'B列の最終行(≒150万行目)から「Ctrl+↑」で移動して止まった位置の行番号
    '⇒B列に●が入力されている一番下の行番号
    lastRow = Cells(Rows.Count, "B").End(xlUp).Row
    
    Dim i As Long
    
    '行を削除すると、行番号がずれてしまうため、下から上へと対象行を削除する
    For i = lastRow To 3 Step -1
        
        'B列のi行目のセルに値が入力されている場合
        '※「….Value = "●"」でも可
        If Cells(i, "B").Value <> "" Then

            'i行目を削除する
            Rows(i).Delete
            
        End If
        
    Next i
    
End Sub

上記のコードの解説をします。

Dim lastRow As Long

Dim と書かれているものは変数宣言と呼び、プログラム内で一時的に使用する値を格納する部屋（変数）を用意しています。
As の後に部屋（変数）の種類を定義しています。
Long は整数を格納する専用の部屋（変数）を指します。

lastRow = Cells(Rows.Count, "B").End(xlUp).Row

Rows.Count で対象のシートの最大の行番号（1048576）を取得できます。
Cells(Rows.Count, “B”) でセルB1048576を指定し、 .End(xlUp) でCtrlキーと↑キーを押した先に移動しています。
Ctrlキーと↑キーを同時に押すと、対象列の次に値が入力されているセルまで移動することができます。
その移動した先のセルの行番号を .Row で取得しています。

For i = lastRow To 3 Step -1 ～ Next i

For ～ Next 間を、先ほど取得した行番号から3まで-1刻みで繰り返します。
変数（i）が先ほど取得した行番号から3まで-1刻みで変化して、For ～ Next の中の処理が繰り返し実行されます。

If Cells(i, "B").Value <> "" Then ～ End If

If ～ End If の中の処理に関して、 Cells(i, “B”).Value <> “” の条件を満たした場合のみ実行します。
Cells(i, “B”).Value は対象のi行目のB列のセルを指しており、 .Value でそのセルの値を取得しています。
<> は等しくないという意味を表しており、 <> “” で空白でないという意味になります。

Rows(i).Delete

Rows(i) でi行目の全体を指定し、 .Delete で削除しています。

上記の内容を記述し、エディタ内の実行ボタン、もしくは、[マクロ]の実行ボタンにて実行すると、B列に値が入力された行全体が削除されます。

※マクロを実行すると、実行前の状態に戻すことができなくなるため、動作確認をする前に、保存をしておくと良いです。

▼サンプルファイル▼

下記の成績一覧表を元に、点数が60点以上の方のみに合格証のシートを発行する方法について解説していきます。

発行する合格証のテンプレートは以下になります。

こちらでは、VBAを用いて開発していきます。
VBAに関して、一度も開発したことがない場合は、下記よりVBAの基礎をご確認ください。

＞VBAの基礎（4-04くらいまでの理解が必要です）

では、開発していきます。
[開発]タブの中の[マクロ]から”合格証発行”という名前で以下のように開発します。

Option Explicit '省略可 変数の宣言を強制する

Sub 合格証発行()
    
    Dim ws1 As Worksheet, ws2 As Worksheet
    Set ws1 = Worksheets("成績一覧")
    Set ws2 = Worksheets("合格証")
    
    Dim lastRow As Long
    lastRow = ws1.Cells(ws1.Rows.Count, "B").End(xlUp).Row
    
    Dim i As Long
    For i = 3 To lastRow
        '発行条件
        If ws1.Cells(i, "D").Value >= 60 Then
            ws2.Copy After:=Worksheets(Worksheets.Count) '合格証発行
            With Worksheets(Worksheets.Count)
                .Name = ws1.Cells(i, "C").Value 'シート名
                .Range("C4").Value = ws1.Cells(i, "C").Value & " 様" '合格者名
            End With
        End If
    Next i
    
End Sub

１）[ws1,ws2]：シート情報を格納する用の変数を用意し"成績一覧"シートと"合格証"シートを設定する

２）[lastRow]："成績一覧"シートの表のデータが入力されている最後の行番号を取得する
→「ws1.Cells(ws1.Rows.Count, "B")」で"成績一覧"シートのB列の最終行を選択し、「.End(xlUp)」で「Ctrl+↑」して移動して止まった位置の行番号「.Row」を取得する

３）[For~Next]："成績一覧"シートのD列(点数)の値が60点以上のデータを3行目から「２）」で取得した行数まで確認する
→60点以上の場合は、「ws2.Copy After:=Worksheets(Worksheets.Count)」で"合格証"シートをコピーし、最後尾にシートを追加する
→コピーした最後尾のシート名を「.Name = ws1.Cells(i, "C").Value」で合格者の名前に変更し、合格証の合格者の名前を「Range("C4").Value = ws1.Cells(i, "C").Value」で"○○様（○○は合格者名）"という値に変更する

こちらの内容を実行すると、以下のように合格者にだけ合格証のシートが作成されます。

[補足] 発行されたシートのみを全て印刷したい場合は、合格証の最初のシート「増井星輝」を選択し、Shiftキーを押しながら最後のシート「野上将文」を選択します。
そのようにすると、以下のように一括で複数シートを選択することができます。

この状態で「Ctrl+P」などで印刷画面に移り、[設定]にて「作業中のシートを印刷」を選択することで、一括で印刷することができます。

セルB2:C2に、以下のような「ON・OFFボタン」を開発してみました。

セルB2:C2のどちらかを選択すると、ONとOFFが切り替わるようになっています。
「ONの時にどうなるのか」といった機能は割り当てていませんが、上記の場合、「セルB2にONという文字が入力されている場合」という条件を使うことで、好みの機能を割り当てることはできます。

では、ON・OFFボタンの開発方法について解説していきます。

特定のシート上の特定のセルを操作した際に自動で処理を実行するには、シートモジュール上にコードを記述する必要があります。

＞５つのモジュールの違いと使い分け

まず初めに、[開発]タブの中の[Visual Basic]を選択します。

開かれたエディター画面にて、[プロジェクト]から実装したいシートモジュールを選択します。
※「Option Explicit」は設定によっては表示されていないかと思いますが、特に問題ございません。
　プロジェクトウィンドウが表示されていない場合は、[表示]タブから表示できます。

次に、特定のセルを選択した際に、自動で処理を実行するためのイベントプロシージャを用意します。
下記のリストから[Worksheet]を選択します。

[Worksheet]を選択すると、以下のようなプロシージャが表示されるかと思います。
※他のプロシージャが表示される場合は、右側のリストより[SelectionChange]を選択してください。

このプロシージャが、該当するシート上のセルの選択が変更された際に自動で処理が実行されるイベントプロシージャになります。
実行時に選択されていたセルの情報は、引数のTargetに渡されます。

その情報を活用して開発していきます。

以下のように、記述します。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    
    '1つのセルのみが選択されている場合
    If Target.CountLarge = 1 Then
        
        'セルB2もしくはC2が選択された場合
        If Target.Row = 2 And _
            (Target.Column = 2 Or Target.Column = 3) Then
            
            'セルB2の背景色が白色の場合
            If Range("B2").Interior.Color = RGB(255, 255, 255) Then
                Range("B2").Value = "ON"
                Range("C2").ClearContents
                Range("B2").Interior.Color = RGB(0, 255, 0)
                Range("C2").Interior.ColorIndex = 0
            Else
                Range("B2").ClearContents
                Range("C2").Value = "OFF"
                Range("B2").Interior.ColorIndex = 0
                Range("C2").Interior.Color = RGB(255, 0, 0)
            End If
            
        End If
    End If
    
End Sub

上記の内容は、以下のような処理になります。

1.選択されているセルが1つのみの場合に、次の処理を実行
2.選択されているセルの行番号が2で、列番号が2もしくは3の場合に、次の処理を実行
3.セルB2の背景色が無色(白色)の場合に、3-1の処理を実行、異なる場合は、3-2の処理を実行
3-1.セルB2の値を"ON"にし、セルC2の値を削除し、セルB2の背景色を緑色にし、セルC2の背景色を白色にする
3-2.セルB2の値を削除し、セルC2の値を"OFF"にし、セルB2の背景色を白色にし、セルC2の背景色を赤色にする

※無色と白色は異なります。無色にしたい場合は、以下のように記述します。

Range("XX").Interior.ColorIndex = 0

上記のコードを記述することで、ON・OFFを切り替えられるボタンを実装することができます。

▼サンプルファイル▼

Excelのマクロ開発に使われるプログラミング言語には、VBAとOfficeスクリプトがあります。
Officeスクリプトに関しては、2021年5月27日に一般公開された比較的新しい言語になります。

デスクトップ版のExcelでは、VBAでマクロ開発ができるのですが、Web版ではVBAを使うことができません。
そこでWeb版のExcelのマクロ開発用として登場したのが、Officeスクリプトになります。

現時点では、デスクトップ版のExcelでもOfficeスクリプトを使用することができるのですが、スクリプトファイルはExcelファイルとは別で、OneDrive上で管理する必要があります。
そのため、ネットに繋がっていないパソコンのExcelでは実行することができません。（2023年6月22日時点）

Officeスクリプトが使用できるライセンスは現時点では以下になります。

・Microsoft 365 Apps for business
・Microsoft 365 Business Standard
・Microsoft 365 Apps for enterprise
・Office 365 ProPlus for Devices
・Office 365 Enterprise E3
・Office 365 Enterprise E5
・Office 365 A3
・Office 365 A5

365でも家族向けのFamilyやPersonalではなく、一般法人向けである必要があるので、新規で登録する場合は注意する必要があります。

OfficeスクリプトはWeb業界では一般的なプログラミング言語「JavaScript」をベースとしています。
もう少し細かく解説すると、「JavaScript」をベースにMicrosoft社によって２０１４年頃に発表された「TypeScript」をベースとした言語になっています。

VBAを理解している方の場合は、比較的、簡単にOfficeスクリプトを理解できるかと思います。

こちらでは、そんなVBAとOfficeスクリプトのコードの違いを簡単に比較していきたいと思います。

今回、VBAとOfficeスクリプトで作成する内容は以下になります。

・A列に〇が入力されている行を削除する

VBAで開発した内容とOfficeスクリプトで開発した内容は以下になります。
アルゴリズム（仕組み）をVBAに寄せてOfficeスクリプトで開発しています。

処理の流れは以下になります。

1.アクティブシートの情報を取得(ws)
2.A列に〇が入力されている最終行の行番号を取得(lastRow)
→シート上のA列の最終行を選択し、「Ctrl+↑」で移動して選択した位置にあるセルの行番号を取得
3.対象の表の範囲を取得(rng)
4.繰り返し文(for)で、手順2で取得した最終行から表の先頭行までを繰り返し、A列に値が入力されている場合は、対象行(A列からC列)を削除して上に詰める

※あくまで一例のため、他の方法でも実現は可能になります。

比較すると、書き方は大きく異なってはいるのですが、全体の構造は似ているかと思います。
Officeスクリプトに挑戦してみたい方は、基礎コンテンツを用意しているため、ご確認ください。

＞Officeスクリプトの基礎

コピーして活用できるようにコードを載せておきます。

Sub 対象行の削除()
    
    Dim sh As Worksheet
    Set sh = ActiveWorkbook.ActiveSheet
    
    Dim lastRow As Integer
    lastRow = sh.Cells(sh.Rows.Count, "A").End(xlUp).Row
    
    Dim rng As Variant
    rng = sh.Range(sh.Cells(1, 1), sh.Cells(lastRow, 1)).Value
    
    Dim i As Long
    
    For i = lastRow To 3 Step -1
        If rng(i, 1) <> "" Then
            sh.Range(sh.Cells(i, 1), sh.Cells(i, 3)).Delete Shift:=xlShiftUp
        End If
    Next i
    
End Sub

function main(workbook: ExcelScript.Workbook) {
    // Your code here

    const sh = workbook.getActiveWorksheet();
    var maxRow = sh.getRange('A:A').getRowCount();
    var lastRow = sh.getCell(maxRow - 1,0).getRangeEdge(ExcelScript.KeyboardDirection.up).getRowIndex() + 1;
    var rng = sh.getRangeByIndexes(0,0,lastRow,1).getValues();
    
    for (var i = lastRow - 1; i >= 2; i--){
        if (String(rng[i]) != ''){
            sh.getRangeByIndexes(i,0,1,3).delete(ExcelScript.DeleteShiftDirection.up);
        }
    }
}

シート上の特定のセル範囲をダブルクリックするだけで、セルの背景色を黄色（黄色の際はリセット）する方法について解説しています。
こちらの内容を応用することで、塗りつぶしではなく、文字を変更したりすることも可能です。
※完成例は記事の最後にて配布しております。

では、以下の範囲（B2～B11）に適用していきます。

特定のシート上をダブルクリックするとプログラムが実行するようにするには、該当するシートモジュール上にプログラムを記述する必要があります。
[開発]タブから[Visual Basic]を選択します。

表示されたVBE（プログラムを記述するウィンドウ）のプロジェクトから、該当するシートをダブルクリックし選択します。
※プロジェクトが表示されていない場合は、[表示]タブの[プロジェクト エクスプローラー]を選択すると表示されます。

上記の操作で表示したものはシートモジュールと呼ばれるもので、シート単位で管理されているプログラムを管理する場所になります。
シートモジュール上の[General]から[Worksheet]を選択します。

ここで表示された「Private Sub Worksheet_SelectionChange]というものは、該当するシート上の選択しているセルが変更された場合に実行される特殊な「イベントプロシージャ」と呼ばれるものになります。
今回はダブルクリックした際に実行するようにしたいため、こちらは使用しません。

「Private Sub Worksheet_SelectionChange]を表示させると、右上に「SelectionChange」と表示されるかと思います。
ここから「BeforeDoubleClick」を選択します。

上記の操作で表示された「Private Sub Worksheet_BeforeDoubleClick」が、セルをダブルクリックすると実行される特殊なイベントプロシージャになります。
今回はこちらを使用します。

先ほどの「Private Sub Worksheet_SelectionChange」は使用しないため、削除して問題ございません。
また「Private Sub Worksheet_BeforeDoubleClick」内に以下のように記述します。
※Option Explicitは必要に応じて削除しても問題ございません。

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    
    If Target.Row >= 2 And Target.Row <= 11 And Target.Column = 2 Then
        Cancel = True
        If Target.Interior.ColorIndex = xlNone Then
            Target.Interior.Color = RGB(255, 255, 0)
        Else
            Target.Interior.ColorIndex = xlNone
        End If
    End If
    
End Sub

簡単にプログラムの内容を解説します。
シート上をダブルクリックすると、「Private Sub Worksheet_BeforeDoubleClick」が実行されます。
また実行時に、「Target」にダブルクリックされたセル情報が入ってきます。

そのため、If文を活用し「Target.Row（ダブルクリックされたセルの行番号）」が２以上かつ１１以下、「Target.Column（ダブルクリックされたセルの列番号）」が２（B列）の時に「If～End If」間の内容が実行されます。
実行時に「Cancel = True」で編集モードになるのを中断しています。

その次に、If文を活用し「Target.Interior.ColorIndex（ダブルクリックされたセルの背景色情報） = xlNone（無色：塗りつぶしなし）」でセルの背景色が無色の場合に「If～Else」間の内容が実行されます。
先ほどの条件を満たしていない場合は、「Else～End If」間の内容が実行されます。

そこで無色の場合は「Target.Interior.Color = RGB(255, 255, 0)」で背景色を黄色に、色が既に設定されている場合は「Target.Interior.ColorIndex = xlNone」で無色にしています。

シートモジュールを含む各モジュールについては下記にて解説しています。
＞各モジュールの違いと使い分け

▼サンプルファイル▼

以下の表の内容をもとに招待状を作成して印刷するという作業を自動化する方法について解説していきます。

まず初めに、できる限り数式を使って招待状を作成できるようにします。
今回の場合は、Noがキーになっているため、Noをもとに、他の氏名や性別が表示されるように以下のように作成します。

=OFFSET(招待者一覧!D2,C3,0) // フリガナ
=OFFSET(招待者一覧!C2,C3,0) // 氏名
=OFFSET(招待者一覧!E2,C3,0) // 性別

こちらではOFFSET関数を使っていますが、場合によってはVLOOKUP関数などでも対応できるかと思います。
今回の場合のOFFSET関数の使い方は以下になります。

=OFFSET(参照, 行数, 列数)
// 参照セルから指定の行数・列数移動した位置のセルの情報を返す

=OFFSET(招待者一覧!D2,C3,0) // フリガナ
// 招待者一覧シートのセルD2を基準にセルC3の数分下へ移動したセルの情報を返す

次に、VBAを使って、Noの値を変更しつつ、招待状シートを印刷します。

[開発]タブの中から[マクロ]を選択し、好みの名前でプログラムを作成します。

こちらでは以下のようなプログラムを作成しています。

Sub 自動印刷()
    
    Dim 開始No As Long: 開始No = 1
    Dim 終了No As Long: 終了No = 20
    
    Dim i As Long
    
    For i = 開始No To 終了No
        Worksheets("招待状").Range("C3").Value = i
        Worksheets("招待状").PrintOut
    Next i
    
End Sub

今回の場合、Noは１からの連番なので、招待状シートのセルC3の値を開始Noから終了Noまで順番に実行しています。
それぞれのNoをセルC3に設定した後に、招待状シートをPrintOutで印刷しています。

このPrintOutは設定されている印刷設定の内容をもとに実行されます。
そのため、こちらのプログラムを実行する前に、印刷設定にて、プリンターや余白などの設定を行う必要があります。

必要に応じてプログラムの一部を変更する必要がありますが、基本はこのようなアルゴリズムで自動化することができます。

▼サンプルファイル▼

以下のようなシートを用意し、B列に”〇”が入力されている行を削除するマクロの作成方法について解説していきます。

まず初めに、B列に”〇”が簡単に入力できるようにドロップダウンリストを作成します。
対象の範囲を選択して、[データ]タブ内の[データの入力規則]にて下記のように設定します。
※入力値の種類を[リスト]にして、元の値に”〇”を入力しています。

これだけでドロップダウンリストの完成です。

では、本題のマクロを開発します。
[開発]タブの中の[マクロ]を選択し、”DeleteRow”という名前で作成します。
※名前は仮です。

プログラムを記述する画面が表示されましたら、以下の内容を記述します。

Sub DeleteRow()
    
    Dim lastRow As Long
    lastRow = Cells(Rows.Count, "B").End(xlUp).Row 'B列の最終行番号を取得
    
    Dim i As Long
    
    For i = lastRow To 3 Step -1 '最終行から3行目まで順番に繰り返す
        If Cells(i, "B").Value <> "" Then 'i行目のB列の値が空白でない場合
            Rows(i).Delete 'i行目の削除
        End If
    Next i
    
End Sub

行を削除すると、行数がずれてしまうため、その対策として最終行から上に向かってB列が空白でないセルを探しています。

最後にボタンを作成します。
[開発]タブの中の[挿入]よりボタンを作成します。（フォームコントロール内のボタン）

作成すると[マクロの登録]が表示されるので、先ほど作成した”DeleteRow”を登録します。

※ボタンの作成後は、クリックすると実行されてしまいます。
　Ctrlキーを押しながらクリックするとボタンを編集できます。

これで完成です。

▼サンプルファイル▼